interchange: Add CMake support for Nexus/prjoxide

Signed-off-by: gatecat <gatecat@ds0.me>

fpga_interchange/examples/chipdb.cmake

@@ -67,6 +67,58 @@ function(create_rapidwright_device_db)
     endif()
 endfunction()
 
+function(create_prjoxide_device_db)
+    # ~~~
+    # create_rapidwright_device_db(
+    #    device <common device>
+    #    output_target <output device target>
+    # )
+    # ~~~
+    #
+    # Generates a device database from Project Oxide
+    #
+    # If output_target is specified, the output_target_name variable
+    # is set to the generated output_device_file target.
+    #
+    # Arguments:
+    #   - device: common device name of a set of parts. E.g. LIFCL-17
+    #   - output_target: variable name that will hold the output device target for the parent scope
+    #
+    # Targets generated:
+    #   - prjoxide-<device>-device
+    set(options)
+    set(oneValueArgs device output_target)
+    set(multiValueArgs)
+
+    cmake_parse_arguments(
+        create_prjoxide_device_db
+        "${options}"
+        "${oneValueArgs}"
+        "${multiValueArgs}"
+        ${ARGN}
+    )
+
+    set(device ${create_prjoxide_device_db_device})
+    set(output_target ${create_prjoxide_device_db_output_target})
+    set(prjoxide_device_db ${CMAKE_CURRENT_BINARY_DIR}/${device}.device)
+    add_custom_command(
+        OUTPUT ${prjoxide_device_db}
+        COMMAND
+            prjoxide
+            interchange-export
+            ${device}
+            ${prjoxide_device_db}
+    )
+
+    add_custom_target(prjoxide-${device}-device DEPENDS ${prjoxide_device_db})
+    set_property(TARGET prjoxide-${device}-device PROPERTY LOCATION ${prjoxide_device_db})
+
+    if (DEFINED output_target)
+        set(${output_target} prjoxide-${device}-device PARENT_SCOPE)
+    endif()
+
+endfunction()
+
 function(create_patched_device_db)
     # ~~~
     # create_patched_device_db(
@@ -225,6 +277,52 @@ function(generate_xc7_device_db)
     endif()
 endfunction()
 
+function(generate_nexus_device_db)
+    # ~~~
+    # generate_nexus_device_db(
+    #    device <common device>
+    #    part <part>
+    #    device_target <variable name for device target>
+    # )
+    # ~~~
+    #
+    # Generates a chipdb BBA file, starting from a Project Oxide device database.
+    # Patches applied:
+    #   - constraints patch
+    #   - luts patch
+    #
+    # Arguments:
+    #   - device: common device name of a set of parts. E.g. LIFCL-17
+    #   - part: one among the parts available for a given device (currently ignored)
+    #   - device_target: variable name that will hold the output device target for the parent scope
+    set(options)
+    set(oneValueArgs device part device_target)
+    set(multiValueArgs)
+
+    cmake_parse_arguments(
+        generate_nexus_device_db
+        "${options}"
+        "${oneValueArgs}"
+        "${multiValueArgs}"
+        ${ARGN}
+    )
+
+    set(device ${generate_nexus_device_db_device})
+    set(part ${generate_nexus_device_db_part})
+    set(device_target ${generate_nexus_device_db_device_target})
+
+    create_prjoxide_device_db(
+        device ${device}
+        output_target prjoxide_device
+    )
+
+    # TODO: any patching that is needed
+
+    if(DEFINED device_target)
+        set(${device_target} ${prjoxide_device} PARENT_SCOPE)
+    endif()
+endfunction()
+
 function(generate_chipdb)
     # ~~~
     # generate_chipdb(

fpga_interchange/examples/devices/CMakeLists.txt

@@ -5,3 +5,6 @@ add_subdirectory(xc7a200t)
 
 # Zynq-7 devices
 add_subdirectory(xc7z010)
+
+# Nexus devices
+add_subdirectory(LIFCL-17)

fpga_interchange/examples/devices/LIFCL-17/CMakeLists.txt

@@ -0,0 +1,14 @@
+generate_nexus_device_db(
+    device LIFCL-17
+    part LIFCL-17-7SG72C
+    device_target lifcl17_target
+)
+
+generate_chipdb(
+    family ${family}
+    device LIFCL-17
+    part LIFCL-17-7SG72C
+    device_target ${lifcl17_target}
+    device_config ${PYTHON_INTERCHANGE_PATH}/test_data/nexus_device_config.yaml
+    test_package QFN72
+)