Update machxo2 backend with build system changes.

machxo2/CMakeLists.txt

@@ -0,0 +1,91 @@
+cmake_minimum_required(VERSION 3.5)
+project(chipdb-machxo2 NONE)
+
+# set(ALL_MACHXO2_DEVICES 256 640 1200 2000 4000 7000)
+set(ALL_MACHXO2_DEVICES 1200)
+set(MACHXO2_DEVICES 1200 CACHE STRING
+    "Include support for these MachXO2 devices (available: ${ALL_MACHXO2_DEVICES})")
+message(STATUS "Enabled MachXO2 devices: ${MACHXO2_DEVICES}")
+
+if(DEFINED MACHXO2_CHIPDB)
+    add_custom_target(chipdb-machxo2-bbas ALL)
+else()
+    find_package(PythonInterp 3.5 REQUIRED)
+
+    # shared among all families
+    set(SERIALIZE_CHIPDBS TRUE CACHE BOOL
+        "Serialize device data preprocessing to minimize memory use")
+
+    set(TRELLIS_PROGRAM_PREFIX "" CACHE STRING
+        "Trellis name prefix")
+    if(TRELLIS_PROGRAM_PREFIX)
+        message(STATUS "Trellis program prefix: ${TRELLIS_PROGRAM_PREFIX}")
+    endif()
+
+    set(TRELLIS_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX} CACHE STRING
+        "Trellis install prefix")
+    message(STATUS "Trellis install prefix: ${TRELLIS_INSTALL_PREFIX}")
+
+    if(NOT DEFINED TRELLIS_LIBDIR)
+        if(WIN32)
+            set(pytrellis_lib pytrellis.pyd)
+        else()
+            set(pytrellis_lib pytrellis${CMAKE_SHARED_LIBRARY_SUFFIX})
+        endif()
+        find_path(TRELLIS_LIBDIR ${pytrellis_lib}
+            HINTS ${TRELLIS_INSTALL_PREFIX}/lib/${TRELLIS_PROGRAM_PREFIX}trellis
+            PATHS ${CMAKE_SYSTEM_LIBRARY_PATH} ${CMAKE_LIBRARY_PATH}
+            PATH_SUFFIXES ${TRELLIS_PROGRAM_PREFIX}trellis
+            DOC "Location of the pytrellis library")
+        if(NOT TRELLIS_LIBDIR)
+            message(FATAL_ERROR "Failed to locate the pytrellis library")
+        endif()
+    endif()
+    message(STATUS "Trellis library directory: ${TRELLIS_LIBDIR}")
+
+    if(NOT DEFINED TRELLIS_DATADIR)
+        set(TRELLIS_DATADIR ${TRELLIS_INSTALL_PREFIX}/share/${TRELLIS_PROGRAM_PREFIX}trellis)
+    endif()
+    message(STATUS "Trellis data directory: ${TRELLIS_DATADIR}")
+
+    set(all_device_bbas)
+    file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/chipdb)
+    foreach(device ${MACHXO2_DEVICES})
+        if(NOT device IN_LIST ALL_MACHXO2_DEVICES)
+            message(FATAL_ERROR "Device ${device} is not a supported MachXO2 device")
+        endif()
+
+        set(device_bba chipdb/chipdb-${device}.bba)
+        add_custom_command(
+            OUTPUT ${device_bba}
+            COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/facade_import.py
+                -L ${TRELLIS_LIBDIR}
+                -L ${TRELLIS_DATADIR}/util/common
+                -L ${TRELLIS_DATADIR}/timing/util
+                -p ${CMAKE_CURRENT_SOURCE_DIR}/constids.inc
+                ${device}
+                > ${device_bba}.new
+            # atomically update
+            COMMAND ${CMAKE_COMMAND} -E rename ${device_bba}.new ${device_bba}
+            DEPENDS
+                ${CMAKE_CURRENT_SOURCE_DIR}/facade_import.py
+                ${CMAKE_CURRENT_SOURCE_DIR}/constids.inc
+                ${PREVIOUS_CHIPDB_TARGET}
+            VERBATIM)
+        list(APPEND all_device_bbas ${device_bba})
+        if(SERIALIZE_CHIPDBS)
+            set(PREVIOUS_CHIPDB_TARGET ${CMAKE_CURRENT_BINARY_DIR}/${device_bba})
+        endif()
+    endforeach()
+
+    add_custom_target(chipdb-machxo2-bbas ALL DEPENDS ${all_device_bbas})
+
+    get_directory_property(has_parent PARENT_DIRECTORY)
+    if(has_parent)
+        set(MACHXO2_CHIPDB ${CMAKE_CURRENT_BINARY_DIR}/chipdb PARENT_SCOPE)
+        # serialize chipdb build across multiple architectures
+        set(PREVIOUS_CHIPDB_TARGET chipdb-machxo2-bbas PARENT_SCOPE)
+    else()
+        message(STATUS "Build nextpnr with -DMACHXO2_CHIPDB=${CMAKE_CURRENT_BINARY_DIR}")
+    endif()
+endif()

machxo2/facade_import.py

@@ -1,8 +1,19 @@
 #!/usr/bin/env python3
-import pytrellis
-import database
 import argparse
 import json
+import sys
+
+parser = argparse.ArgumentParser(description="import MachXO2 routing and bels from Project Trellis")
+parser.add_argument("device", type=str, help="target device")
+parser.add_argument("-p", "--constids", type=str, help="path to constids.inc")
+parser.add_argument("-g", "--gfxh", type=str, help="path to gfx.h (unused)")
+parser.add_argument("-L", "--libdir", type=str, action="append", help="extra Python library path")
+args = parser.parse_args()
+
+sys.path += args.libdir
+import pytrellis
+import database
+
 
 class BinaryBlobAssembler:
     def l(self, name, ltype = None, export = False):
@@ -57,12 +68,6 @@ dev_names = {"1200": "LCMXO2-1200HC"}
 def main():
     global max_row, max_col, const_id_count
 
-    parser = argparse.ArgumentParser(description="import MachXO2 routing and bels from Project Trellis")
-    parser.add_argument("device", type=str, help="target device")
-    parser.add_argument("-p", "--constids", type=str, help="path to constids.inc")
-    parser.add_argument("-g", "--gfxh", type=str, help="path to gfx.h (unused)")
-    args = parser.parse_args()
-
     pytrellis.load_database(database.get_db_root())
 
     bba = BinaryBlobAssembler()

machxo2/family.cmake

@@ -1,114 +1,51 @@
 if (BUILD_GUI)
-    message(FATAL_ERROR "GUI support is not implemented for MachXO2.")
+    message(FATAL_ERROR "GUI support is not implemented for MachXO2. Build with -DBUILD_GUI=OFF.")
+endif()
+add_subdirectory(${family})
+message(STATUS "Using MachXO2 chipdb: ${MACHXO2_CHIPDB}")
+
+set(chipdb_sources)
+set(chipdb_binaries)
+file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${family}/chipdb)
+foreach(device ${MACHXO2_DEVICES})
+    set(chipdb_bba ${MACHXO2_CHIPDB}/chipdb-${device}.bba)
+    set(chipdb_bin ${family}/chipdb/chipdb-${device}.bin)
+    set(chipdb_cc  ${family}/chipdb/chipdb-${device}.cc)
+    if(BBASM_MODE STREQUAL "binary")
+        add_custom_command(
+            OUTPUT ${chipdb_bin}
+            COMMAND bbasm ${BBASM_ENDIAN_FLAG} ${chipdb_bba} ${chipdb_bin}
+            DEPENDS bbasm chipdb-${family}-bbas ${chipdb_bba})
+        list(APPEND chipdb_binaries ${chipdb_bin})
+    elseif(BBASM_MODE STREQUAL "embed")
+        add_custom_command(
+            OUTPUT ${chipdb_cc} ${chipdb_bin}
+            COMMAND bbasm ${BBASM_ENDIAN_FLAG} --e ${chipdb_bba} ${chipdb_cc} ${chipdb_bin}
+            DEPENDS bbasm chipdb-${family}-bbas ${chipdb_bba})
+        list(APPEND chipdb_sources ${chipdb_cc})
+        list(APPEND chipdb_binaries ${chipdb_bin})
+    elseif(BBASM_MODE STREQUAL "string")
+        add_custom_command(
+            OUTPUT ${chipdb_cc}
+            COMMAND bbasm ${BBASM_ENDIAN_FLAG} --c ${chipdb_bba} ${chipdb_cc}
+            DEPENDS bbasm chipdb-${family}-bbas ${chipdb_bba})
+        list(APPEND chipdb_sources ${chipdb_cc})
+    endif()
+endforeach()
+if(WIN32)
+    list(APPEND chipdb_sources
+        ${CMAKE_CURRENT_SOURCE_DIR}/${family}/resource/embed.cc
+        ${CMAKE_CURRENT_SOURCE_DIR}/${family}/resource/chipdb.rc)
 endif()
 
-if (NOT EXTERNAL_CHIPDB)
+add_custom_target(chipdb-${family}-bins DEPENDS ${chipdb_sources} ${chipdb_binaries})
-    set(devices 1200)
 
-    set(TRELLIS_PROGRAM_PREFIX "" CACHE STRING "Name prefix for trellis")
+add_library(chipdb-${family} OBJECT ${MACHXO2_CHIPDB} ${chipdb_sources})
+add_dependencies(chipdb-${family} chipdb-${family}-bins)
+target_compile_options(chipdb-${family} PRIVATE -g0 -O0 -w)
+target_compile_definitions(chipdb-${family} PRIVATE NEXTPNR_NAMESPACE=nextpnr_${family})
+target_include_directories(chipdb-${family} PRIVATE ${family})
 
-    if (NOT DEFINED TRELLIS_INSTALL_PREFIX)
+foreach(family_target ${family_targets})
-        message(STATUS "TRELLIS_INSTALL_PREFIX not defined using -DTRELLIS_INSTALL_PREFIX=/path-prefix/to/prjtrellis-installation. Defaulted to ${CMAKE_INSTALL_PREFIX}")
+    target_sources(${family_target} PRIVATE $<TARGET_OBJECTS:chipdb-${family}>)
-        set(TRELLIS_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX})
+endforeach()
-    endif()
-
-    if (NOT DEFINED PYTRELLIS_LIBDIR)
-        find_library(PYTRELLIS pytrellis.so
-            PATHS ${TRELLIS_INSTALL_PREFIX}/lib/${TRELLIS_PROGRAM_PREFIX}trellis
-            PATH_SUFFIXES ${TRELLIS_PROGRAM_PREFIX}trellis
-            DOC "Location of pytrellis library")
-
-        if ("${PYTRELLIS}" STREQUAL "PYTRELLIS-NOTFOUND")
-            message(FATAL_ERROR "Failed to locate pytrellis library!")
-        endif()
-
-        get_filename_component(PYTRELLIS_LIBDIR ${PYTRELLIS} DIRECTORY)
-    endif()
-
-    set(DB_PY ${CMAKE_CURRENT_SOURCE_DIR}/machxo2/facade_import.py)
-
-    file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/machxo2/chipdbs/)
-    add_library(machxo2_chipdb OBJECT ${CMAKE_CURRENT_BINARY_DIR}/machxo2/chipdbs/)
-    target_compile_definitions(machxo2_chipdb PRIVATE NEXTPNR_NAMESPACE=nextpnr_${family})
-    target_include_directories(machxo2_chipdb PRIVATE ${family}/)
-
-    if (CMAKE_HOST_WIN32)
-        set(ENV_CMD ${CMAKE_COMMAND} -E env "PYTHONPATH=\"${PYTRELLIS_LIBDIR}\;${TRELLIS_INSTALL_PREFIX}/share/${TRELLIS_PROGRAM_PREFIX}trellis/util/common\;${TRELLIS_INSTALL_PREFIX}/share/${TRELLIS_PROGRAM_PREFIX}trellis/timing/util\"")
-    else()
-        set(ENV_CMD ${CMAKE_COMMAND} -E env "PYTHONPATH=${PYTRELLIS_LIBDIR}\:${TRELLIS_INSTALL_PREFIX}/share/${TRELLIS_PROGRAM_PREFIX}trellis/util/common:${TRELLIS_INSTALL_PREFIX}/share/${TRELLIS_PROGRAM_PREFIX}trellis/timing/util")
-    endif()
-
-    if (MSVC)
-        target_sources(machxo2_chipdb PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/machxo2/resource/embed.cc)
-        set_source_files_properties(${CMAKE_CURRENT_SOURCE_DIR}/machxo2/resources/chipdb.rc PROPERTIES LANGUAGE RC)
-        set(PREV_DEV_CC_BBA_DB)
-        foreach (dev ${devices})
-            set(DEV_CC_DB ${CMAKE_CURRENT_BINARY_DIR}/machxo2/chipdbs/chipdb-${dev}.bin)
-            set(DEV_CC_BBA_DB ${CMAKE_CURRENT_BINARY_DIR}/machxo2/chipdbs/chipdb-${dev}.bba)
-            set(DEV_CONSTIDS_INC ${CMAKE_CURRENT_SOURCE_DIR}/machxo2/constids.inc)
-            if (PREGENERATED_BBA_PATH)
-                add_custom_command(OUTPUT ${DEV_CC_DB}
-                    COMMAND bbasm ${BBASM_ENDIAN_FLAG} ${PREGENERATED_BBA_PATH}/chipdb-${dev}.bba ${DEV_CC_DB}
-                    )
-            else()
-                add_custom_command(OUTPUT ${DEV_CC_BBA_DB}
-                    COMMAND ${ENV_CMD} ${PYTHON_EXECUTABLE} ${DB_PY} -p ${DEV_CONSTIDS_INC} ${dev} > ${DEV_CC_BBA_DB}
-                    DEPENDS ${DB_PY} ${DEV_CONSTIDS_INC} ${PREV_DEV_CC_BBA_DB}
-                    )
-                add_custom_command(OUTPUT ${DEV_CC_DB}
-                    COMMAND bbasm ${BBASM_ENDIAN_FLAG} ${DEV_CC_BBA_DB} ${DEV_CC_DB}
-                    DEPENDS bbasm ${DEV_CC_BBA_DB}
-                    )
-            endif()
-            if (SERIALIZE_CHIPDB)
-                set(PREV_DEV_CC_BBA_DB ${DEV_CC_BBA_DB})
-            endif()
-            target_sources(machxo2_chipdb PRIVATE ${DEV_CC_DB})
-            set_source_files_properties(${DEV_CC_DB} PROPERTIES HEADER_FILE_ONLY TRUE)
-            foreach (target ${family_targets})
-                target_sources(${target} PRIVATE $<TARGET_OBJECTS:machxo2_chipdb> ${CMAKE_CURRENT_SOURCE_DIR}/machxo2/resource/chipdb.rc)
-            endforeach()
-        endforeach()
-    else()
-        target_compile_options(machxo2_chipdb PRIVATE -g0 -O0 -w)
-        set(PREV_DEV_CC_BBA_DB)
-        foreach (dev ${devices})
-            set(DEV_CC_BBA_DB ${CMAKE_CURRENT_BINARY_DIR}/machxo2/chipdbs/chipdb-${dev}.bba)
-            set(DEV_CC_DB ${CMAKE_CURRENT_BINARY_DIR}/machxo2/chipdbs/chipdb-${dev}.cc)
-            set(DEV_BIN_DB ${CMAKE_CURRENT_BINARY_DIR}/machxo2/chipdbs/chipdb-${dev}.bin)
-            set(DEV_CONSTIDS_INC ${CMAKE_CURRENT_SOURCE_DIR}/machxo2/constids.inc)
-            if (PREGENERATED_BBA_PATH)
-                add_custom_command(OUTPUT ${DEV_CC_DB}
-                    COMMAND bbasm --c ${BBASM_ENDIAN_FLAG} ${PREGENERATED_BBA_PATH}/chipdb-${dev}.bba ${DEV_CC_DB}.new
-                    COMMAND mv ${DEV_CC_DB}.new ${DEV_CC_DB}
-                    )
-            else()
-                add_custom_command(OUTPUT ${DEV_CC_BBA_DB}
-                    COMMAND ${ENV_CMD} ${PYTHON_EXECUTABLE} ${DB_PY} -p ${DEV_CONSTIDS_INC} ${dev} > ${DEV_CC_BBA_DB}.new
-                    COMMAND mv ${DEV_CC_BBA_DB}.new ${DEV_CC_BBA_DB}
-                    DEPENDS ${DB_PY} ${DEV_CONSTIDS_INC} ${PREV_DEV_CC_BBA_DB}
-                    )
-                if(USE_C_EMBED)
-                    add_custom_command(OUTPUT ${DEV_CC_DB}
-                        COMMAND bbasm --e ${BBASM_ENDIAN_FLAG} ${DEV_CC_BBA_DB} ${DEV_CC_DB}.new ${DEV_BIN_DB}
-                        COMMAND mv ${DEV_CC_DB}.new ${DEV_CC_DB}
-                        DEPENDS bbasm ${DEV_CC_BBA_DB}
-                        )
-                else()
-                    add_custom_command(OUTPUT ${DEV_CC_DB}
-                        COMMAND bbasm --c ${BBASM_ENDIAN_FLAG} ${DEV_CC_BBA_DB} ${DEV_CC_DB}.new
-                        COMMAND mv ${DEV_CC_DB}.new ${DEV_CC_DB}
-                        DEPENDS bbasm ${DEV_CC_BBA_DB}
-                        )
-                endif()
-            endif()
-            if (SERIALIZE_CHIPDB)
-                set(PREV_DEV_CC_BBA_DB ${DEV_CC_BBA_DB})
-            endif()
-            target_sources(machxo2_chipdb PRIVATE ${DEV_CC_DB})
-            foreach (target ${family_targets})
-                target_sources(${target} PRIVATE $<TARGET_OBJECTS:machxo2_chipdb>)
-            endforeach()
-        endforeach()
-    endif()
-endif()

machxo2/resource/chipdb.rc

@@ -0,0 +1,3 @@
+#include "resource.h"
+
+IDR_CHIPDB_1200  BINARYFILE "machxo2/chipdb/chipdb-1200.bin"

machxo2/resource/embed.cc

@@ -0,0 +1,24 @@
+#include <cstdio>
+#include <windows.h>
+#include "nextpnr.h"
+#include "resource.h"
+
+NEXTPNR_NAMESPACE_BEGIN
+
+const char *chipdb_blob_1200;
+
+const char *LoadFileInResource(int name, int type, DWORD &size)
+{
+    HMODULE handle = ::GetModuleHandle(NULL);
+    HRSRC rc = ::FindResource(handle, MAKEINTRESOURCE(name), MAKEINTRESOURCE(type));
+    HGLOBAL rcData = ::LoadResource(handle, rc);
+    size = ::SizeofResource(handle, rc);
+    return static_cast<const char *>(::LockResource(rcData));
+}
+void load_chipdb()
+{
+    DWORD size = 0;
+    chipdb_blob_1200 = LoadFileInResource(IDR_CHIPDB_1200, BINARYFILE, size);
+}
+
+NEXTPNR_NAMESPACE_END

machxo2/resource/resource.h

@@ -0,0 +1,2 @@
+#define BINARYFILE 256
+#define IDR_CHIPDB_1200 103