6d2c2aecff
There are two main reasons to desire an OpenGL 2 renderer:
1. Compatibility. The compatibility profile, ironically, does not
offer a lot of compatibility, and our OpenGL 1 renderer will not
run on Android, iOS, or WebGL.
2. Performance. The immediate mode does not scale, and in fact
becomes very slow with only a moderate amount of lines on screen,
and only a somewhat large amount of triangles.
This commit implements a basic OpenGL 2 renderer that uses only
features from the (OpenGL 3.2) core profile. It is not yet faster
than the OpenGL 1 renderer, primarily because it uses a lot of small
draw calls.
This commit uses OpenGL 2 on Linux and Mac OS X directly (i.e. links
to the GL symbols from version 2+); on Windows this is impossible
with the default drivers, so for now OpenGL 1 is still used there.
63 lines
1.9 KiB
GLSL
63 lines
1.9 KiB
GLSL
//-----------------------------------------------------------------------------
|
|
// SolveSpace Outline rendering shader
|
|
//
|
|
// Copyright 2016 Aleksey Egorov
|
|
//-----------------------------------------------------------------------------
|
|
#version 120
|
|
|
|
const int EMPHASIZED_AND_CONTOUR = 0;
|
|
const int EMPHASIZED_WITHOUT_CONTOUR = 1;
|
|
const int CONTOUR_ONLY = 2;
|
|
|
|
const float feather = 0.5;
|
|
|
|
attribute vec3 pos;
|
|
attribute vec4 loc;
|
|
attribute vec3 tan;
|
|
attribute vec3 nol;
|
|
attribute vec3 nor;
|
|
|
|
uniform mat4 modelview;
|
|
uniform mat4 projection;
|
|
uniform float width;
|
|
uniform float pixel;
|
|
uniform int mode;
|
|
|
|
varying vec3 fragLoc;
|
|
|
|
void main() {
|
|
// get camera direction from modelview matrix
|
|
vec3 dir = vec3(modelview[0].z, modelview[1].z, modelview[2].z);
|
|
|
|
// perform outline visibility test
|
|
float ldot = dot(nol, dir);
|
|
float rdot = dot(nor, dir);
|
|
|
|
bool isOutline = (ldot > -1e-6) == (rdot < 1e-6) ||
|
|
(rdot > -1e-6) == (ldot < 1e-6);
|
|
bool isTagged = loc.w > 0.5;
|
|
|
|
float visible = float((mode == CONTOUR_ONLY && isOutline) ||
|
|
(mode == EMPHASIZED_AND_CONTOUR && (isOutline || isTagged)) ||
|
|
(mode == EMPHASIZED_WITHOUT_CONTOUR && isTagged && !isOutline));
|
|
|
|
// calculate line contour extension basis for constant width and caps
|
|
vec3 norm = normalize(cross(tan, dir));
|
|
norm = normalize(norm - dir * dot(dir, norm));
|
|
vec3 perp = normalize(cross(dir, norm));
|
|
|
|
// calculate line extension width considering antialiasing
|
|
float ext = (width + feather * pixel) * visible;
|
|
|
|
// extend line contour
|
|
vec3 vertex = pos;
|
|
vertex += ext * loc.x * normalize(perp);
|
|
vertex += ext * loc.y * normalize(norm);
|
|
|
|
// write fragment location for calculating caps and antialiasing
|
|
fragLoc = vec3(loc);
|
|
|
|
// transform resulting vertex with modelview and projection matrices
|
|
gl_Position = projection * modelview * vec4(vertex, 1.0);
|
|
}
|